创胜支付接口文件及相关脚本

SET QUOTED_IDENTIFIER ON
SET ANSI_NULLS ON
GO
USE RYTreasureDB
GO

----------------------------------------------------------------------------------
-- 申请订单
CREATE PROCEDURE NET_PW_applyOnLineOrder
    @strOrderID            NVARCHAR(32),                -- 订单编号
    @dwOperUserID          INT,                        -- 操作用户ID
    @dwShareID             INT,                        -- 服务类型
    @dwProductType         INT,                        -- 充值类型
    @dwAppID               INT,                        -- 充值应用ID
    @strAccounts           NVARCHAR(31),               -- 充值用户
    @dcOrderAmount         DECIMAL(18,2),              -- 订单金额
    @strIPAddress          NVARCHAR(15),               -- 支付IP地址
    @strErrorDescribe      NVARCHAR(127) OUTPUT        -- 错误描述信息
AS

-- 设定基础属性
SET NOCOUNT ON

-- 账号信息
DECLARE @Accounts NVARCHAR(31)
DECLARE @GameID INT
DECLARE @UserID INT
DECLARE @Nullity TINYINT
DECLARE @StunDown TINYINT

-- 订单信息
DECLARE @OrderID NVARCHAR(32)
DECLARE @OrderAmount DECIMAL(18,2)
DECLARE @PayAmount DECIMAL(18,2)
DECLARE @Currency DECIMAL(18,2)
DECLARE @Rate INT

BEGIN
    -- 验证用户
    SELECT @UserID = UserID, @GameID = GameID, @Accounts = Accounts, @Nullity = Nullity, @StunDown = StunDown
    FROM RYAccountsDBLink.RYAccountsDB.dbo.AccountsInfo
    WHERE Accounts = @strAccounts

    IF @UserID IS NULL
    BEGIN
        SET @strErrorDescribe = N'用户账号不存在，请检查输入信息！'
        RETURN 1
    END

    IF @Nullity = 1
    BEGIN
        SET @strErrorDescribe = N'该账户当前被冻结，请联系平台客服咨询详情。'
        RETURN 2
    END

    IF @StunDown <> 0
    BEGIN
        SET @strErrorDescribe = N'此账号已开启安全关闭功能，需重新激活后方可继续充值。'
        RETURN 3
    END

    -- 确认订单是否存在
    SELECT @OrderID = OrderID FROM OnLineOrder WHERE OrderID = @strOrderID
    IF @OrderID IS NOT NULL
    BEGIN
        SET @strErrorDescribe = N'该订单号已存在，请重新提交订单。'
        RETURN 4
    END

    -- 确认汇率信息
    SELECT @Rate = StatusValue FROM RYAccountsDBLink.RYAccountsDB.dbo.SystemStatusInfo 
    WHERE StatusName = 'RateCurrency'

    IF @Rate IS NULL
        SET @Rate = 1

    -- 计算订单金额
    SET @OrderAmount = @dcOrderAmount
    SET @PayAmount = @dcOrderAmount
    SET @Currency = @PayAmount * @Rate

    -- 插入新订单数据
    INSERT INTO OnLineOrder(
        OperUserID, ShareID, UserID, GameID, Accounts, OrderID, OrderAmount, PayAmount, Rate, Currency, IPAddress)
    VALUES(
        @dwOperUserID, @dwShareID, @UserID, @GameID, @Accounts, @strOrderID, @OrderAmount, @PayAmount, 0, @Currency, @strIPAddress)

    SELECT @dwOperUserID AS OperUserID, @dwShareID AS ShareID, @UserID AS UserID, @GameID AS GameID, @Accounts AS Accounts,
           @strOrderID AS OrderID, @OrderAmount AS OrderAmount, @PayAmount AS PayAmount, @Rate AS Rate, @Currency AS Currency, @strIPAddress AS IPAddress       
END
RETURN 0
GO